请问debug中无法load源码文件该怎么办？

你在调什么？什么映象？

我在调试日本的一个OS，t-kernel
有2个镜像，一个是T-Monitor，一个是T-Kernel
T-Monitor类似bootloader，地址是0x0开始的
T-Kernel就是kernel程序，地址是0x20000开始的
编译器用的是Sourcery G++ Lite for ARM EABI

装载T-Monitor的镜像，是可以load源码的
装载T-Kernel的镜像，就不可以

然后我尝试，kernel和monitor一同编译
但是这个镜像也是不能被load的

求教

你看看它们的编译地址是什么，如果有编译脚本，就贴出来

OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(__text_start)


SECTIONS {
    .text 0x00000000 : {
        __text_start = .;
        KEEP (*(.init))
        *(.text)
        *(.text.*)
        *(.stub)
        KEEP (*(.fini))
        PROVIDE (__etext = .);
        PROVIDE (_etext = .);
        PROVIDE (etext = .);
        *(.rodata)
        *(.rodata.*)
        *(.rodata1)
        . = ALIGN(10);

    } =0
    ___data_org = .;
    .dest 0x30004440 : AT (___data_org) {
        ___data_start = . ;
        *(.data)
        *(.data.*)
        SORT(CONSTRUCTORS)
        *(.data1)
        KEEP (*(.eh_frame))
        *(.gcc_except_table)
        KEEP (*crtbegin.o(.ctors))
        KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
        KEEP (*(SORT(.ctors.*)))
        KEEP (*(.ctors))
        KEEP (*crtbegin.o(.dtors))
        KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
        KEEP (*(SORT(.dtors.*)))
        KEEP (*(.dtors))
        *(.sdata)
        *(.sdata.*)
        . = ALIGN(4);
        __edata = .;
        PROVIDE (edata = .);
    }
    .bss ALIGN(4) : {
        ___bss_start = .;
        PROVIDE (__***ss_start = .);
        PROVIDE (___***ss_start = .);
        *(.***ss)
        *(.***ss.*)
        *(.scommon)
        PROVIDE (__***ss_end = .);
        PROVIDE (___***ss_end = .);
        *(.bss)
        *(.bss.*)
        *(COMMON)
        . = ALIGN(4);
        _end = .;
        PROVIDE (end = .);
    }
}

上面这个是monitor的link文件（monitor是可load的）
下面这个是kernel的link文件（kernel现在是无法load的）

OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)

SECTIONS {
        .text 0x00020000 : {
                KEEP (*(.init))
                *(.text)
                *(.text.*)
                *(.stub)
                KEEP (*(.fini))
                PROVIDE (__etext = .);
                PROVIDE (_etext = .);
                PROVIDE (etext = .);
                *(.rodata)
                *(.rodata.*)
                *(.rodata1)
                . = ALIGN(0x10);
        } =0
       
        .ARM.extab :{*(.ARM.extab*) *(.gnu.linkonce.armextab.*)}
        __exidx_start = .;
        .ARM.exidx   : { *(.ARM.exidx* .gnu.linkonce.armexidx.*) }
        __exidx_end = .;

        __data_org = . ;
        .data 0x30006000 : AT(__data_org) {
                __data_start = . ;
                *(.data)
                *(.data.*)
                SORT(CONSTRUCTORS)
                *(.data1)
                KEEP (*(.eh_frame))
                *(.gcc_except_table)
                KEEP (*crtbegin.o(.ctors))
                KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
                KEEP (*(SORT(.ctors.*)))
                KEEP (*(.ctors))
                KEEP (*crtbegin.o(.dtors))
                KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
                KEEP (*(SORT(.dtors.*)))
                KEEP (*(.dtors))
                *(.sdata)
                *(.sdata.*)
                . = ALIGN(4);
                _edata = .;
                PROVIDE (edata = .);
        }
        .bss ALIGN(4) : {
                __bss_start = .;
                PROVIDE (__***ss_start = .);
                PROVIDE (___***ss_start = .);
                *(.***ss)
                *(.***ss.*)
                *(.scommon)
                PROVIDE (__***ss_end = .);
                PROVIDE (___***ss_end = .);
                *(.bss)
                *(.bss.*)
                *(COMMON)
                . = ALIGN(0x4);
                _end = .;
                PROVIDE (end = .);
        }
}

是S3C2410或S33C2440吗？
对于下面的程序，加载地址是0x00020000 ；但是S3C2410、S3C2440在0地址只有4K的内存，即0地址开始的地址是0～0x1000