Clubber累加器进入asm内联不起作用

HI，与纯汇编文件中的实际操作相比，联机DSPIC汇编语法非常有限（而且复杂）。我强烈鼓励您将ASM文件添加到C项目中。XC16编译器手册描述了如果要传递参数，则如何将参数存储在堆栈中。从C中恢复值



      以下为原文

    Hi,
The in-line dsPIC assembly syntax is very limitating (and complex) compared to what you can actually do in a pure assembly file.
I strongly encourage you to add ASM files to your C project.
The XC16 compiler manual describes how parameters are stored in the stack if you want to pass parameters and recover values from C.
Regards
 

如果希望的话，有内置的C函数与累加器一起工作。



      以下为原文

    There are built-in C functions to work with accumulator if you wish.

我看到了BuffdIn函数，但我发现它们比ASM内联的要复杂得多……而且，对于我的情况，我不能用ApHyBuuthTuxIn Mac WeAsMac指令来增加增量W13。例如，我选择了ASM内联来获得一个指令号，但我想我会忘记和处理。用一个单独的ASM文件按照你的建议。所以，我没有犯错误吗？我们不能参与累加器吗？



      以下为原文

    I saw the build_in function but I find them again more complicated than asm inline...
Moreover for my case, I cannot post-increment W13 with __built_in_MAC wheareas MAC asm instruction can, for example.
 
I chose asm inline to gain a couple of instruction number, but I think I will forget that and deal with a separate asm file as you suggest.
 
So, I did not make mistake ? We can not clubber accumulators ?

汇编程序一路。当用内联编码时，你必须小心，看起来丑陋，需要更长的代码。编译器会填写额外的东西来获取它们需要的寄存器。最重要的是，任何阅读内联的人都必须理解内联。编码可能需要10倍的时间。错误更难于发现，而是将参数传递给汇编程序代码。



      以下为原文

    Assembler all the way.
 
When coding with inline you have to take care of clobbering, looks ugly and takes a longer to code.  There are additional stuff the compiler will fill in to get the registers where they need to be.  On top of that, anyone else reading inline will have to understand inline as well.  It could take 10 times longer to code.  Mistakes are harder to spot.
 
Pass parameters to assembler code instead.
.include "xc.inc"
.include "LCD7920Lib.inc"
.global _lcd7920_line
.section lcd7920code,code
;----------------------------------------------------
.equ arg_XS,        w0
.equ arg_YS,        w1
.equ arg_XE,        w2
.equ arg_YE,        w3
.equ arg_Color,        w4
.equ offsetx,        w4    ;reuse
.equ offsety,        w5
.equ tmpx,          w6
.equ tmpy,          w7
.equ cnt,           w8
.equ xpos,          w9
.equ ypos,         w10
.equ dir,          w11
.equ color,        w12

_lcd7920_line:
    ;check if already opened
    btss    LCD7920_Flag,#LCD7920FLAG_OPEN
    retlw   #LCD7920ERROR_NOTOPEN,w0
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;horizontal line? use fast draw
    cp      arg_YS,arg_YE
    bra     nz,$+8
    sub     arg_XE,arg_XS,w2    ;width
    mov     #1,w3               ;height
    bra     _lcd7920_srect
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;single pixel?
    cp        arg_XS,arg_XE
    bra        nz,drawline
    cp        arg_YS,arg_YE
    bra        nz,drawline
    mov        arg_Color,w2
    bra        lcd7920_plot
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
drawline:
    ;save regs high
    push.d  w8
    push.d  w10
    push    w12
    mov        arg_Color,color
    mov        arg_XS,xpos
    mov        arg_YS,ypos
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;x axis and y axis difference
    sub        arg_XE,arg_XS,offsetx
    sub        arg_YE,arg_YS,offsety
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;absolute for dominant axis
    mov        offsetx,tmpx
    btsc    tmpx,#15
    neg        tmpx,tmpx
    mov        offsety,tmpy
    btsc    tmpy,#15
    neg        tmpy,tmpy
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;dominant x, y or the same?
    cp        tmpy,tmpx
    bra        z,samexy
    bra        gtu,yaxis
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;X axis direction
    mov        #1,dir
    cp        arg_XS,arg_XE
    bra        ltu,$+4
    mov        #-1,dir
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;abs
    btsc    offsetx,#15
    neg        offsetx,offsetx
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;zero offset?
    clr        A
    cp0        w2
    bra        nz,$+6
    clr        B
    bra        zerox
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;divide and load B
    mov        offsetx,w2
    repeat  #18-1
    divf    offsety,w2
    lac        w0,#-1,B
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
zerox:
    inc        offsetx,cnt
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
looplix:
    ;plot x,y,color
    mov        xpos,w0
    mov        #ACCAU,w2
    add        ypos,[w2],w1
    mov        color,w2
    rcall   lcd7920_plot
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;next
    add        A
    add        xpos,dir,xpos
    dec        cnt,cnt
    bra        nz,looplix
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;done
    pop        w12
    pop.d   w10
    pop.d   w8
    retlw   #LCD7920ERROR_OK,w0
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;Y axis direction
yaxis:
    mov        #1,dir
    cp        arg_YS,arg_YE
    bra        ltu,$+4
    mov        #-1,dir
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;abs
    btsc    offsety,#15
    neg        offsety,offsety
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;zero offset?
    clr        A
    cp0        w2
    bra        nz,$+6
    clr        B
    bra        zeroy
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;divide and load B
    mov        offsety,w2
    repeat  #18-1
    divf    offsetx,w2
    lac        w0,#-1,B
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
zeroy:
    inc        offsety,cnt
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;plot x,y,color
loopliy:
    mov        #ACCAU,w2
    add        xpos,[w2],w0
    mov        ypos,w1
    mov        color,w2
    rcall   lcd7920_plot
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;next
    add        A
    add        ypos,dir,ypos
    dec        cnt,cnt
    bra        nz,loopliy
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;done
    pop        w12
    pop.d   w10
    pop.d   w8
    retlw   #LCD7920ERROR_OK,w0
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
samexy:
    ;X axis direction
    mov        #1,dir
    cp        arg_XS,arg_XE
    bra        ltu,$+4
    mov        #-1,dir
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;Y axis direction
    mov        #1,w0
    cp        arg_YS,arg_YE
    bra        ltu,$+4
    mov        #-1,w0
    mov        w0,ACCAH
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;abs
    btsc    offsetx,#15
    neg        offsetx,offsetx
    inc        offsetx,cnt
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
loopsame:
    ;plot x,y,color
    mov        xpos,w0
    mov        ypos,w1
    mov        color,w2
    rcall   _lcd7920_plot
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;next
    add        xpos,dir,xpos
    mov        #ACCAH,w2
    add        ypos,[w2],ypos
    dec        cnt,cnt
    bra        nz,loopsame
    ;~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ;done
    pop        w12
    pop.d   w10
    pop.d   w8
    retlw   #LCD7920ERROR_OK,w0
;----------------------------------------------------
.end