采集到的12位AD值怎么处理？

平均值是除法运算，不管什么运算，多字节的数值是一个整体，是不可能分开计算的。可以上网找一些需要用的算法，如果可以的话，可以改用C语言编程。
下面的算法也是网上找的。
;
;        r7 r6 r5 /r4 r3 = r7 r6 r5...r2 r1 r0
;
unsigned_24_bit_division:
                push        11h
                push        12h
                push        13h
                mov        r0,#00h
                mov        r1,#00h
                mov        r2,#00h
                mov        11h,#00h
                mov        12h,#00h
                mov        13h,#00h
                mov        b,#24
unsigned_24_bit_division_1:
                clr        c
                mov        a,r5
                rlc        a
                mov        r5,a
                mov        a,r6
                rlc        a
                mov        r6,a
                mov        a,r7
                rlc        a
                mov        r7,a
                mov        a,r0
                rlc        a
                mov        r0,a
                mov        a,r1
                rlc        a
                mov        r1,a
                mov        a,r2
                rlc        a
                mov        r2,a
                clr        c
                mov        a,r0
                subb        a,r3
                mov        dpl,a
                mov        a,r1
                subb        a,r4
                mov        dph,a
                mov        a,r2
                subb        a,#00h
                mov        0ch,a
                cpl        c
                jnc        unsigned_24_bit_division_2
                mov        a,dpl
                mov        r0,a
                mov        a,dph
                mov        r1,a
                mov        a,0ch
                mov        r2,a
unsigned_24_bit_division_2:
                mov        a,0dh
                rlc        a
                mov        0dh,a
                mov        a,0eh
                rlc        a
                mov        0eh,a
                mov        a,0fh
                rlc        a
                mov        0fh,a
                djnz        b,unsigned_24_bit_division_1
                mov        a,0dh
                mov        r5,a
                mov        a,0eh
                mov        r6,a
                mov        a,0fh
                mov        r7,a
                pop        13h
                pop        12h
                pop        11h
                ret

8位以上，16位以下的用双字节加减操作，16位-24位的用三字节加减法，这个在51的汇编教材里应该有例子，也可以在网上找，要注意多次求和后的数值范围，如果超过2字节，则最后的和值就需要三字节长度了

采样精度本身是否够，如果不够那就不用搞了；如果显示数据不稳定，可以考虑采用滤波算法，网上有一些简单的滤波算法

本帖最后由 人中狼 于 2018-11-5 10:35 编辑

measure_times是ADC转换次数
temp_0,temp_1,temp_2是多次ADC转换值的和，temp_0为高字节


                                 mov       r2,#measure_times
measure_ad_1:
                                lcall          adc_convert              ;AD转换
                               mov                a,ADRL
                               mov                ADRL_BUFF,A
                                mov                        a,ADRH
                                mov                        ADRH_BUFF,A
                                mov        a,temp_2
                                add        a,ADRL_BUFF
                               mov        temp_2,a
                                mov        a,temp_1
                                addc        a,ADRH_BUFF
                               mov        temp_1,a
                                 mov        a,temp_0
                                 addc        a,#00h
                                 mov        temp_0,a
                                 djnz        r2,measure_ad_1

最后的进位，如果最后累加结果超过2个字节，那么要进位到第3个字节，但是没有其他数值需要与第3个字节相加，所以就加零