uboot的重定位与搬移地址冲突

board_init_f程序执行后的搬移地址与CONFIG_SYS_TEXT_BASE不一致

我不熟悉你这款芯片，但是新版本的uboot是会进行两次重定位的：先搬运到board_init_f指定的地址，再搬运到CONFIG——SYS——TEXT——BASE 指定的地址

回复 2楼wuweidong的帖子

你说的两次重定位，就是两次代码搬移(relocate)，是吗？还有我只看见有一次代码搬移呢！
就在下面代码大致位置：
程序执行了board_inti_f之后，跳转如下：
/* Set initial stackpointer in SDRAM to call board_init_f */
call_board_init_f:
        ldr        sp, =(CONFIG_SYS_INIT_SP_ADDR)
        bic        sp, sp, #7 /* 8-byte alignment for ABI compliance */
        ldr        r0,=0x00000000
        bl        board_init_f

/*------------------------------------------------------------------------------*/

/*
* void relocate_code (addr_sp, gd, addr_moni)
*
* This "function" does not return, instead it continues in RAM
* after relocating the monitor code.
*
*/
        .globl        relocate_code
relocate_code:
        mov        r4, r0        /* save addr_sp */
        mov        r5, r1        /* save addr of gd */
        mov        r6, r2        /* save addr of destination */

        /* Set up the stack                                                    */
stack_setup:
        mov        sp, r4

        adr        r0, _start
        cmp        r0, r6
        beq        clear_bss                /* skip relocation */
        mov        r1, r6                        /* r1 <- scratch for copy_loop */
        ldr        r3, _bss_start_ofs
        add        r2, r0, r3                /* r2 <- source end address            */

copy_loop:
        ldmia        r0!, {r9-r10}                /* copy from source address [r0]    */
        stmia        r1!, {r9-r10}                /* copy to   target address [r1]    */
        cmp        r0, r2                        /* until source end address [r2]    */
        blo        copy_loop
#ifndef CONFIG_PRELOADER
        /*
         * fix .rel.dyn relocations
         */
        ldr        r0, _TEXT_BASE                /* r0 <- Text base */
        sub        r9, r6, r0                /* r9 <- relocation offset */
        ldr        r10, _dynsym_start_ofs        /* r10 <- sym table ofs */
        add        r10, r10, r0                /* r10 <- sym table in FLASH */
        ldr        r2, _rel_dyn_start_ofs        /* r2 <- rel dyn start ofs */
        add        r2, r2, r0                /* r2 <- rel dyn start in FLASH */
        ldr        r3, _rel_dyn_end_ofs        /* r3 <- rel dyn end ofs */
        add        r3, r3, r0                /* r3 <- rel dyn end in FLASH */
fixloop:
        ldr        r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
        add        r0, r0, r9                /* r0 <- location to fix up in RAM */
        ldr        r1, [r2, #4]
        and        r7, r1, #0xff
        cmp        r7, #23                        /* relative fixup? */
        beq        fixrel
        cmp        r7, #2                        /* absolute fixup? */
        beq        fixabs
        /* ignore unknown type of fixup */
        b        fixnext
fixabs:
        /* absolute fix: set location to (offset) symbol value */
        mov        r1, r1, LSR #4                /* r1 <- symbol index in .dynsym */
        add        r1, r10, r1                /* r1 <- address of symbol in table */
        ldr        r1, [r1, #4]                /* r1 <- symbol value */
        add        r1, r1, r9                /* r1 <- relocated sym addr */
        b        fixnext
fixrel:
        /* relative fix: increase location by offset */
        ldr        r1, [r0]
        add        r1, r1, r9
fixnext:
        str        r1, [r0]
        add        r2, r2, #8                /* each rel.dyn entry is 8 bytes */
        cmp        r2, r3
        blo        fixloop
#endif

clear_bss:
#ifndef CONFIG_PRELOADER
        ldr        r0, _bss_start_ofs
        ldr        r1, _bss_end_ofs
        mov        r4, r6                        /* reloc addr */
        add        r0, r0, r4
        add        r1, r1, r4
        mov        r2, #0x00000000                /* clear                            */

clbss_l:str        r2, [r0]                /* clear loop...                    */
        add        r0, r0, #4
        cmp        r0, r1
        bne        clbss_l

        bl coloured_LED_init
        bl red_LED_on
#endif

/*
* We are done. Do not return, instead branch to second part of board
* initialization, now running from RAM.
*/
        ldr        r0, _board_init_r_ofs
        adr        r1, _start
        add        lr, r0, r1
        add        lr, lr, r9
        /* setup parameters for board_init_r */
        mov        r0, r5                /* gd_t */
        mov        r1, r6                /* dest_addr */
        /* jump to it ... */
        mov        pc, lr
。。。
就跳转到c程序board_init_r，就没看见哪儿有搬移代码了！

还有，我想问，uboot好像只能定义一个CONFIG_SYS_TEXT_BASE，也就是所谓的运行地址，board_init_r程序代码就是相对于这运行地址偏移的，为什么还需要计算，不就ldr pc,board_init_r 就可以了吗？为什么还需要一次搬移呢！？我是新手，望楼主能给予详细点说明，先谢谢了！

uboot除start.S后面的c代码，链接地址与运行地址不一致，应该是运行不起撒？这知识点应该没问题吧？

终于知道是搬移了符号表，这样新版本的uboot中的CONFIG_SYS_TEXT_BASE实际上在搬移代码后变的并不重要了，只是在搬移代码前的c代码必须链接地址与运行地址一致。